Imports System
Imports System.Collections.Generic
Imports System.Text

Imports SMath.Manager
Imports SMath.Control

Public Class Implementer : Implements IPluginCustomRegion
    Dim assemblyInfos() As AssemblyInfo
    Dim menuButtons() As MenuButton
    Dim dragDropFileTypes() As DragAndDropFileType

    Public Function CreateNew() As SMath.Control.RegionBase Implements SMath.Control.IPluginCustomRegion.CreateNew
        Return New CheckBox()
    End Function

    Public ReadOnly Property DragAndDropFileTypes As SMath.Control.DragAndDropFileType() Implements SMath.Control.IPluginCustomRegion.DragAndDropFileTypes
        Get
            ' No Drag'n'Drop files supported
            Return Me.dragDropFileTypes
        End Get
    End Property

    Public Function GetContextMenuItems(region As SMath.Control.RegionBase) As SMath.Control.MenuButton() Implements SMath.Control.IPluginCustomRegion.GetContextMenuItems
        Return New MenuButton() {New MenuButton("xxx")}
    End Function

    Public ReadOnly Property IsCurrentClipboardSupported As Boolean Implements SMath.Control.IPluginCustomRegion.IsCurrentClipboardSupported
        Get
            ' No external clipboard data supported
            Return False
        End Get
    End Property

    Public ReadOnly Property MenuItems As SMath.Control.MenuButton() Implements SMath.Control.IPluginCustomRegion.MenuItems
        Get
            Return Me.menuButtons
        End Get
    End Property

    Public ReadOnly Property Dependences As SMath.Manager.AssemblyInfo() Implements SMath.Manager.IPlugin.Dependences
        Get
            Return Me.assemblyInfos
        End Get
    End Property

    Public Sub InsertCheckbox(args As MenuButtonArgs)
        args.CurrentRegion = New CheckBox()
    End Sub

    Public Sub Initialize() Implements SMath.Manager.IPlugin.Initialize
        Me.assemblyInfos = New AssemblyInfo() {New AssemblyInfo("SMath Studio", New Version(0, 90), New Guid("a37cba83-b69c-4c71-9992-55ff666763bd"))}
        Me.dragDropFileTypes = New DragAndDropFileType() {New DragAndDropFileType(Nothing, Nothing)}
        Me.menuButtons = New MenuButton() {New MenuButton("CheckBox", AddressOf Me.InsertCheckbox)}
    End Sub

#Region "IDisposable Support"
    Private disposedValue As Boolean ' To detect redundant calls

    ' IDisposable
    Protected Overridable Sub Dispose(disposing As Boolean)
        If Not Me.disposedValue Then
            If disposing Then
                ' TODO: dispose managed state (managed objects).
            End If

            ' TODO: free unmanaged resources (unmanaged objects) and override Finalize() below.
            ' TODO: set large fields to null.
        End If
        Me.disposedValue = True
    End Sub

    ' TODO: override Finalize() only if Dispose(ByVal disposing As Boolean) above has code to free unmanaged resources.
    'Protected Overrides Sub Finalize()
    '    ' Do not change this code.  Put cleanup code in Dispose(ByVal disposing As Boolean) above.
    '    Dispose(False)
    '    MyBase.Finalize()
    'End Sub

    ' This code added by Visual Basic to correctly implement the disposable pattern.
    Public Sub Dispose() Implements IDisposable.Dispose
        ' Do not change this code.  Put cleanup code in Dispose(ByVal disposing As Boolean) above.
        Dispose(True)
        GC.SuppressFinalize(Me)
    End Sub
#End Region

End Class

Imports System
Imports System.Collections.Generic
Imports System.Text
Imports System.Windows.Forms
Imports System.Drawing
Imports System.Xml

Imports SMath.Manager
Imports SMath.Control

Public Class CheckBox : Inherits SMath.Control.RegionEvaluable
    Dim bChecked As Boolean

    Public Sub New()
        MyBase.New()
        Me.bChecked = False
        MyBase.Terms = New Term() {New Term("checked", TermType.Operand, 0)}
        MyBase.Size = New Size(22, 22)
    End Sub

    Public Sub New(region As CheckBox)
        MyBase.New(region)
        Me.bChecked = region.Checked
    End Sub

    Public Overrides Sub Evaluate(store As SMath.Math.Store)
        If (MyBase.Terms.Length = 1) And (MyBase.Terms(0).Type = TermType.Operand) Then
            If bChecked Then
                store.AddDefinition(MyBase.Terms(0).Text, New Term() {New Term("1", TermType.Operand, 0)}, Nothing)
            Else
                store.AddDefinition(MyBase.Terms(0).Text, New Term() {New Term("0", TermType.Operand, 0)}, Nothing)
            End If
        End If
    End Sub

    Public Overrides Function Clone() As SMath.Control.RegionBase
        Return New CheckBox(Me)
    End Function

    Public Overrides Sub FromXml(reader As System.Xml.XmlTextReader, parsingContext As SMath.Control.FileParsingContext)
        Me.bChecked = Convert.ToBoolean(reader.GetAttribute("checked"))
    End Sub

    Public Overrides Sub ToXml(writer As System.Xml.XmlTextWriter, parsingContext As SMath.Control.FileParsingContext)
        writer.WriteAttributeString("checked", Me.bChecked.ToString.ToLower)
    End Sub

    Public Overrides Sub OnCommandSend(s As String)
        If s = " " Then
            Me.Focused = True
            Me.InDate = False
            bChecked = Not bChecked
            ' Request evaluation as soon as value changes
            RequestForEvaluation(CalculateType.Numeric, Me, False)
        End If
        MyBase.OnCommandSend(s)
    End Sub

    Public Overrides Sub OnPaint(e As PaintEventArgs)
        MyBase.OnPaint(e)
        If bChecked Then
            e.Graphics.FillRectangle(Brushes.Black, e.ClipRectangle.X + 1, e.ClipRectangle.Y + 1, e.ClipRectangle.Width - 2, e.ClipRectangle.Height - 2)
        Else
            e.Graphics.FillRectangle(Brushes.LightGray, e.ClipRectangle.X + 1, e.ClipRectangle.Y + 1, e.ClipRectangle.Width - 2, e.ClipRectangle.Height - 2)
        End If
    End Sub

    Public Overrides Sub OnMouseDown(e As MouseEventArgs)
        MyBase.OnMouseDown(e)
        OnCommandSend(" ")
    End Sub

    Public Property Checked()
        Get
            Return bChecked
        End Get
        Set(value)
            bChecked = value
        End Set
    End Property

End Class